HOME 0 | Diary 1 |

【私的】USBブート非対応PC用起動フロッピーを作るの巻【その2】

INDEX 2

  1. これって何？
  2. ダウンロード
  3. FreeDOS起動ディスク
  4. 分割ファイル作成
  5. スクリーンショット
HOME 0| Diary 1

Get Firefox

リンク is フリーダム♪

2021.4.1 移転しました...
  • このページの旧URLは
    • http://www10.plala.or.jp/palm84/fdboot_liveusb2.html

はてなブックマーク

2008.4.13 作成
【Palm84的設定ファイル詰め合わせ】については甚だ不完全なのでコロコロ修正すると思います。
2009.7.2 選択OSを【合体編】に合わせました。（更新が楽になるようにと...）
2009.7.4 備考と注意点と関連リンクを整理しました。

ご案内してみたり...
  1. その1 === DOS用USBドライバでUSBデバイスを直接認識
  2. その2 === 分割ファイルをコピーした複数枚FDからブート
    • ↑今ここ
  3. 合体編 === 【その1】と【その2】を合体
  4. GRUB編 === 【合体編】をFDイメージへ、PLoP Boot Managerを追加

内容が重複しまくっとります。恐れ入り奉りまする。Palm84的【設定ファイル詰め合わせ】については甚だ不完全なのでコロコロ修正すると思います。

2009.7 色々イジリ更新しました。古い版は下記にて。

2008.8.17追記

こんなのありましたー。

上記のページのやつが使えるなら（※USB CDは非対応）、このページに書いてるやつはいらないですね...。orz

下記ページの続き、かなーり私的な内容です...

及び、下記ページの第2弾ということで。

とりあえず下記のものについて設定を書いてみた。

チェックはしてますけど多少間違いあるかも？ご容赦をば。

あくまでFDしかブート手段がない、あるいはHD上にファイルをコピーできない状態でのお話。ネットワークブート可能ならサーバ上からカーネルをロード、HDへファイルのコピーが可能なら、GRUB(for DOS、またはNTFSパッチなど)起動ディスクでHD（NTFSでもおｋ！）上のファイルをロードしてブートできますし。

■ これって何？

USBメモリ、USB CDブートに対応していないPCにて、DOS起動FDからブートして、分割したLinuxカーネル（とミニルートイメージ）をFDから読み込んでRAMドライブ上に展開、Linuxローダー(linld.com, loadlin.exe) からカーネルをロードさせてUSBデバイス上のLinux LiveCDをブートさせようというものなのでありやす。

【その1】の方法との違い
デメリット
  • FDの枚数が増える。入替が面倒クサ。読み込みに時間がかかる

Knoppix、SLAXでは+3枚。SystemRescueCdではデフォルトのセットだけでなんと+8枚。

で、ありますが【その1】でだめだった場合に試す価値あるかも？

メリット
  • DOS用USBドライバが不要
  • DOSで認識できなかったUSBデバイス（USBカードリーダなど）でもLinux上では認識可能なことがよくあります

下記ページにあるのは、Fedora Core 5のインストール用なのですが、非常に便利なのでこれを元に作成することにしました。（必要なのは1枚目のFreeDOS起動ディスクイメージだけです。）

起動の流れはこんなかんじ...

  1. RAMディスクドライバを組み込んだFreeDOS起動ディスクでブート
  2. RAMドライブを作成
  3. コマンドなど必要ファイルをFDからRAMドライブへコピー
  4. FDからLinuxカーネルの分割ファイルを読み込み
  5. 分割ファイルを結合してRAMドライブ上に展開
  6. LINLD.COM(loadlin.exe)でカーネルとinitrd（初期RAMディスクイメージ）をロード
  7. （ミニ）Linuxが起動しUSBデバイスを検出して認識
  8. Linuxルートイメージをサーチしてマウント
もっとｋｗｓｋ
  1. TDSK.EXEをロード。24MBのRAMドライブ作成
  2. RAMドライブへ移動 (TURBODAT.exe,RDRIVE.BAT)
  3. 必要ファイルをRAMドライブへコピー
  4. FDから分割ファイルを読み込み、結合して展開 (copyb.bat)
  5. 選択に従いLinux起動用batファイル実行 (knoppix.bat)
  6. menu.txtを表示
  7. choice.exeを実行、選択したオプション（パラメータ）でLINLD.COMがカーネルとinitrdをロード
  8. LinuxがUSBデバイスを検出

■ ダウンロードしておくもの

FDへ直接書き込む
イメージからファイルを取り出し
FDイメージからファイルを取り出すには（イメージをファイルに展開）

下記の Universal Extractor が便利かも。 UniExtract Binary Archive はインストール不要で使えます（日本語表示も可）。

※注意：対象ファイルのパスに‘デスクトップ’など日本語が含まれるとエラーになるみたいです。

FDに一旦書き込むか、展開する、仮想ドライブでマウントするなどしてファイルを取り出しておく

  • RAMディスクドライバなどを含むディスクイメージ

fc5fd.tar.bz2を作者様への感謝の気持ちを込めてダウンロード。FC5-FloppyInstall-1.imgを展開

  • xcopy.exe, edit.exe, keyb.exe, keyboard.sys, keybrd2.sys
    • balder10.img（FDイメージなのでFDに書き込むか展開する）
ファイルのダウンロード
Palm84的設定ファイル詰め合わせ

あくまでPalm84的なので内容の保証は全くありません。（汗）

展開してそのままFDへコピーするだけー

GRUB for DOS 関連

必須ではないけど GRUB for DOS も入れるなら下記を追加しませう。

0.4.3.zip（または 0.4.4.zip）をダウンロード（0.4.3の方がサイズが小さいです）。必要なのは grub.exe のみ。

ネットワークブート用カーネル
  • Choose NIC/ROM type
    • gpxe:all-drivers を選択
  • Choose ROM output format
    • LILO/GRUB/SYSLINUX loadable Linux kernel format (.lkrn) を選択
    • [Get ROM] をポチっと
  • gpxe-git-gpxe.lkrn は gpxe_all.krn にリネーム
Memtest86+ (memtest86+-2.01.bin)

（※最新版の方がいいと思いますけど、旧版はサイズが若干小さいので）【Pre-Compiled Bootable Binary】をダウンロードして展開。ファイル名を memtest にリネーム。。

BG-Rescue Linux 0.9.1

これはUSBデバイス不要です。FD +2枚で起動。（vmlinuzとinitrd.imgをそれぞれFDにコピーしておく）

■ FreeDOS起動ディスク

  1. ディスク作成
  2. choice.exeでメニュー表示
  3. 起動の流れ

■ ディスク作成

  1. fdboot.imgをRawWrite for WindowsなどでFDへ書き込み
    • A:\fdconfig.sysを削除
  2. FC5-FloppyInstall-1.imgから起動ディスクルートへ
    • appld.bat
    • HOME.DAT
    • LDFD.ZIP
    • license.txt
    • loadlin.exe
    • RDRIVE.BAT
    • ReadMe.txt
    • TDSK.EXE
    • TURBO.DAT
    • TURBODAT.exe
    • UNZIP.EXE
    • version.txt
  3. balder10.img
    • xcopy.exe, edit.exe を A:\freedos へ
    • keyb.exe, keyboard.sys, keybrd2.sysを A:\driver へ
  4. ダウンロードしておいたLINLD.COMを A:\freedos に
  5. 設定ファイルを作成・編集（またはPalm84的詰め合わせをコピー）

（※ここ古いページのままになっておりました。すみません。）

とりあえずこんな風に。

A:.
|   appld.bat
|   command.com
|   HOME.DAT
|   kernel.sys
|   LDFD.ZIP
|   license.txt
|   RDRIVE.BAT
|   ReadMe.txt
|   TDSK.EXE
|   TURBO.DAT
|   TURBODAT.exe
|   UNZIP.EXE
|   version.txt
|
+---driver
|       devload.com
|       himem.exe
|       keyb.exe
|       keyboard.sys
|       keybrd2.sys
|
\---freedos
        choice.exe
        edit.exe
        LINLD.COM
        xcopy.exe
GRUB for DOS も入れるなら...
  • grub.exe をルートへ
  • gpxe-git-gpxe.lkrn を gpxe_all.krn にリネームしてルートへ
  • memtest をルートへ

A:\menu.lst と A:\grub ディレクトリ内のファイルがあるか確認。

設定ファイルを作成・編集

※またはPalm84的詰め合わせをコピー

  • A:\config.sys （作成）
!switches=/f /n
menucolor=0,3
REM menudefault=0,10
menu
menu  ===========================================
menu      FreeDOS USB support -- LiveUSB boot
menu  ===========================================
menu
menu     0 - === Load Ramdisk TURBO.DAT   === 
menu
menu      ### Linux LiveCD/LiveUSB Boot  ###
menu
menu     1 - == GRUB for DOS  or  FreeDOS  ==
menu
menu         ###  Memtest             ###
menu         ###  gPXE Network Boot   ###
menu         ###  BG-Rescue Linux     ###
menu
menu  ===========================================
menu

1?shell=command.com command.com /P
REM 012345678?shell=command.com /e:1024 /p
0?DEVICE=a:\driver\himem.exe
0?DOSDATA=UMB
0?DOS=HIGH,UMB
!FILES=20
!BUFFERS=20
!LASTDRIVE=Z
0?stacks=9,256
0?DEVICE=A:\TDSK.EXE 24576
  • A:\autoexec.bat （作成）
@ECHO OFF
if %CONFIG% == 1 goto FREEDOS
if %CONFIG% == 0 goto load_ram


:load_ram
a:\bin\auto_ram.bat
goto END

:FREEDOS
REM ########################      FREEDOS        #########################
cls
echo          ============================================================
echo          ================  FreeDOS  boot options ====================
echo          ============================================================
echo.
echo          ====     1.  GRUB for DOS  -- grub.exe                  ====
echo.
echo          ====     2.  FreeDOS       -- load HIMEM,KEYB           ====
echo.
echo          ====     3.  FreeDOS       -- clean boot                ====
echo.
echo          ============================================================
echo.
a:\freedos\choice.exe /C:1234X Type Number:

if ERRORLEVEL 4 GOTO END
if ERRORLEVEL 3 GOTO END
if ERRORLEVEL 2 GOTO HIMEM
if ERRORLEVEL 1 GOTO GRUB

:HIMEM
a:\driver\devload.com a:\driver\himem.exe
set path=a:\bin;a:\freedos
a:\driver\keyb jp
goto END

:GRUB
a:\grub.exe
goto END

:END
  • A:\bin\auto_ram.bat
@ECHO OFF
if %CONFIG% == 1 goto END

A:\TURBODAT.EXE
copy TURBO.DAT RDRIVE.BAT
call RDRIVE.BAT
copy nul ramdrive.txt
for %%y in ( C D E F G H I J ) do if exist %%y:\ramdrive.txt set ramdrv=%%y:
copy a:\UNZIP.EXE
copy a:\APPLD.BAT
copy a:\LDFD*.*
copy a:\menu.txt
copy a:\reload.bat
a:\freedos\xcopy.exe /i /s a:\bin %ramdrv%\bin
a:\freedos\xcopy.exe /i /s a:\freedos %ramdrv%\freedos
if exist a:\options.txt copy a:\options.txt
set path=%ramdrv%\bin;%ramdrv%\freedos
a:\driver\keyb jp

:END
start.bat
  • A:\bin\start.bat（選択メニュー表示）
@echo off
cls
type %ramdrive%\menu.txt
choice /C:123456789X boot:
IF ERRORLEVEL=10 GOTO END
GOTO %ERRORLEVEL%

:1
xcopy /i /s a:\knop53 %ramdrv%\knop53
set boot=knoppix3
cls
copyb.bat
GOTO END

:2
xcopy /i /s a:\knop5 %ramdrv%\knop5
set boot=knoppix
cls
copyb.bat
GOTO END

:3
xcopy /i /s a:\slax5 %ramdrv%\slax5
set boot=slax
cls
copyb.bat
GOTO END

:4
xcopy /i /s a:\sysres1 %ramdrv%\sysres1
set boot=sysres
cls
copyb.bat
GOTO END

:5
xcopy /i /s a:\berry90 %ramdrv%\berry90
set boot=berry
cls
copyb.bat
GOTO END

:6
xcopy /i /s a:\puppy400 %ramdrv%\puppy400
set boot=puppy
cls
copyb.bat
GOTO END

:7
xcopy /i /s a:\inse12 %ramdrv%\inse12
set boot=insert
cls
insert.bat
GOTO END

:8
xcopy /i /s a:\bgrescue %ramdrv%\bgrescue
set boot=bgrescue
cls
bgrescue.bat
GOTO END

:9
if not exist a:\grub.exe goto nogrub
a:
a:\grub.exe
goto END

:nogrub
echo.
echo A:\GRUB.EXE not found !!!
echo Insert boot floppy in drive A: ... and press a key
pause >nul
goto 9

:END
cls
  • A:\menu.txt（選択メニュー）
      ================================================================
                          Linux LiveCD Boot Menu
      ================================================================

                     Type one of the following numbers:

               1 :     Knoppix 5.3.1 CD - SSK  - from Floppy +4
               2 :     Knoppix 5.1.1 CD - LCR  - from Floppy +3
               3 :     SLAX Live CD 5.1.8.1-3  - from Floppy +3
               4 :     SystemRescueCd 1.0.4    - from Floppy +8?
               5 :     Berry Linux 0.90        - from Floppy +2
               6 :     Puppy Linux 4.xx JP     - from Floppy +3
               7 :     INSERT+ 1.2.18          - from Floppy +2
               8 :     BG-Rescue Linux 0.9.1   - from Floppy +2
               9 :     GRUB for DOS
  • A:\bin\copyb.bat （fedora.batを編集）
@echo off
REM Copy all files to RAM Drive
:docopy
if exist A:\end.txt goto done
pause Insert next floppy and press a key...
copy a:\LDFD*.*
goto docopy

:done
REM Now reconstruct the zipfile
for %%f in (LDFDR*.*) do call appld.bat %%f
del ldfdr*.*
unzip ldfd

if %CONFIG% == 7 goto slaxx
if %CONFIG% == 6 goto knoppixx
if %CONFIG% == 5 goto puppy
if %CONFIG% == 4 goto berry
if %CONFIG% == 2 goto sysres
if %CONFIG% == 1 goto slax
if %CONFIG% == 0 goto knoppix

:slaxx
slaxx.bat

:knoppixx
knoppixx.bat

:puppy
puppy.bat

:berry
berry.bat

:sysres
sysres.bat

:slax
slax.bat

:knoppix
knoppix.bat

:end
  • A:\appld.bat （元のまま）
copy ldfd.zip /b + %1 /b ldfd.tmp
copy ldfd.tmp ldfd.zip
del ldfd.tmp
del %1

■ choice.exeでメニュー表示

@echo off
echo.
echo      ===================================================================
echo                                Type Number
echo.
echo              1 : knoppix_dir=/KNOPPIX/KNOPPIX/    *** default ***
echo.
echo              2 : knoppix_dir=/knoppix3/KNOPPIX/   *** rename  ***
echo.
echo      ===================================================================
choice /C:12X /T:1,10 Type Number:
REM choice /C:12X Type Number:

if ERRORLEVEL 3 GOTO END
if ERRORLEVEL 2 GOTO RENAME
if ERRORLEVEL 1 GOTO DEFAULT

:DEFAULT
set param1=
GOTO MENU

:RENAME
set param1=knoppix_dir=knoppix3 knoppix_name=KNOPPIX
GOTO MENU

:MENU
cls
set menudir=%ramdrv%\knop53
type %menudir%\menu.txt
choice /C:12345678X boot:
IF ERRORLEVEL=9 GOTO END
GOTO %ERRORLEVEL%

:1
set opt=default
set vga=791
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:2
set opt=vesa
set vga=normal
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:3
set opt=text
set vga=normal
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:4
set opt=fb800
set vga=788
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:5
set opt=fb1024
set vga=791
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:6
set opt=fb1280
set vga=794
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:7
set opt=failsafe
set vga=normal
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:8
set opt=test
set vga=normal
if not "%param1%"=="" GOTO TEMP
GOTO LINLD

:LINLD
linld image=linux initrd=minirt.gz vga=%vga% cl=@%menudir%\%opt%.txt
GOTO END

:TEMP
copy %menudir%\%opt%.txt %menudir%\temp.txt
echo   %param1%<>%menudir%\temp.txt
linld image=linux initrd=minirt.gz vga=%vga% cl=@%menudir%\temp.txt
GOTO END

:END

     ===================================================================
                    Knoppix Live CD SSK 5.3.1 Boot Menu
     ===================================================================

                     Type one of the following numbers:

               1 :     default
               2 :     vesa
               3 :     text mode
               4 :     fb 800x600
               5 :     fb 1024x768
               6 :     fb 1280x1024
               7 :     failsafe
               8 :     test (desktop=fluxbox)
               X :      * cancel * 


ramdisk_size=100000 init=/etc/init lang=ja apm=power-off nomce highres=off loglevel=0 libata.atapi_enabled=1 quiet SELINUX_INIT=NO nmi_watchdog=0 BOOT_IMAGE=knoppix

■ 起動の流れ

  1. config.sys で %config% を選択
    • RAMディスクドライバ読み込み
  2. autoexec.bat
    • auto_ram.bat 呼び出し
  3. auto_ram.bat
    • RAMドライブへ移動
    • RAMドライブへコマンドコピー
    • set path=%ramdrv%\bin;%ramdrv%\freedos
  4. start.bat
    • OS選択メニュー表示
    • 選択OSのブート・オプション設定ファイルをコピー
  5. copyb.bat
    • FDから分割ファイル(LDFD*.*)を読み込んでコピー
    • A:\end.txt が出るまで繰り返し
    • appld.bat 呼び出し(LDFD*.*)を LDFD.ZIP に結合して展開
    • 選択OS用batファイル実行
  6. knoppix3.bat（など）
    • (\knop53)menu.txt 表示
    • choice.exe 実行
    • 設定ファイルを読み込み、LINLD 実行

■ 分割ファイル作成

  1. Linuxカーネルと初期RAMディスクイメージをzipで圧縮
    • KNOPPIX 5.3.1CD では（FDx4枚）、\boot\isolinuxのlinuxとminirt.gz
    • Knoppix 5.1.1 CD では（FDx3枚）、\boot\isolinuxのlinuxとminirt.gz
    • slax-ja-5.1.8.1-3 では（FDx3枚）、\bootのvmlinuzとinitrd.gz
    • systemrescuecd-x86-1.0.4（FDx8枚+） では、\isolinuxのrescuecd（※など）とinitram.igz
    • Berry Linux 0.90 では（FDx2枚）、\Setup の vmlinuzとinitrd.gz
    • Puppy Linux 4.1.2.1 では（FDx2枚）、vmlinuzとinitrd.gz
  2. FDサイズに分割
  3. ファイル名はldfdraa,ldfdrab,ldfdrac,...にする
  4. それぞれをFDへそのままコピー
  5. 最終のFDに空ファイル end.txt 作成
Linux上で実行

※KNOPPIX 5.3.1CD の例

$ cp /cdrom/boot/isolinux/linux .
$ cp /cdrom/boot/isolinux/minirt.gz .
$ zip ldfd.zip linux minirt.gz

ldfd.zipが作成されたのを確認して分割ファイル作成（※531通常版は4個、Remastered CD だと3個のファイル）

$ split --verbose -b 1423k ldfd.zip ldfdr
creating file `ldfdraa'
creating file `ldfdrab'
creating file `ldfdrac'
Windows XP上で実行

※KNOPPIX 5.3.1CD の例

  1. CDの\boot\isolinuxフォルダを開く
  2. linuxとminirt.gzとHD上にコピー
  3. linuxとminirt.gzを選択
  4. 右クリック→送る→圧縮（zip 形式）フォルダ
  5. 圧縮・解凍ソフトでzipファイルを開き、1423(1423.5)KBで分割
  6. ファイル名を順に、ldfdraa,ldfdrab,ldfdrac,...にする

+Lhacaでは圧縮形式をZIPに変更。linuxとminirt.gzを選択してAltキーを押しながらショートカットアイコンへドラッグで1200KBの分割ファイルができました。

■ 分割不要な場合

カーネルと初期RAMディスク(initrd)がそれぞれFDに収まるサイズなら分割せずそのままFDへコピーでブート可能な場合もあります。

RAMドライブへのコピーは不要ですけど、やり直しを考えてコピーさせておきます。

Bドライブに入れなさい？

BドライブFD入替メッセージ

ファイルのパスに B:\ を指定するとInsert diskette in Drive B:とメッセージが出ますが、BIOSで2台目のFDDを有効にしていなければ（通常無効）単純に入替で読み込みが可能かと。

INSERT+ 1.2.18

isolinuxディレクトリ内のvmlinuzとminiroot.gzをそれぞれコピー

  • ※RAMドライブなしの場合のコマンド（batファイル）の例
linld image=B:\vmlinuz initrd=A:\miniroot.gz vga=791 cl=@.\inse12\default.txt
BG-Rescue Linux 0.9.1

USBではなく、FD+2枚のみで起動。RAMドライブも不要。

  • ※RAMドライブなしの場合のコマンド（batファイル）の例
linld image=B:\vmlinuz initrd=A:\initrd.img vga=775

■ スクリーンショット

KNOPPIX

Ramdriveの組み込み。Dドライブとなってます。

KNOPPIX

KNOPPIX

必要なファイルのコピーが終わるとOS選択メニューが出ます。

KNOPPIX

「Insert next floppy and press a key」のメッセージが出たら、FDを【ゆっくり】と入れ替えてEnter。ゆっくり入れ替えてからキー押さないと同じファイルをコピーしちゃったりします。

KNOPPIX

KNOPPIX

KNOPPIX

この下のメッセージが出たらフロッピーがおかしいか、入替のタイミングが早すぎるとかです。

KNOPPIX

一部ディレクトリの変更を選択させてます（/knoppix3/KNOPPIX は私のですが...）。10秒放置するとデフォルトの【1】の選択となります。

KNOPPIX

KNOPPIX 5.3.1CDのオプション選択メニュー。数字入力でKnoppixがブート。【x】を打つとキャンセル。再度メニューを表示するには【knoppix3】と打つべし。

KNOPPIX

USBを検索しています。「Allowing slow USB-devices...」のメッセージが出ずその後に止まってしまう場合は、この一つ上のメッセージが出てる時にUSBデバイス挿し直しで認識されることありました。

KNOPPIX

USBメモリから /knoppix3/KNOPPIX が発見されたもより...

KNOPPIX

■ GRUB for DOS の起動画面

【その1】と全く同じだったりしますが.....

FreeDOSから grub.exe を実行させます。

FreeDOS選択メニュー

GRUBの起動画面

BG-Rescue Linuxのメニュー

BG-Rescue Linux 0.9.1 はFD2枚入替のみで、INSERT+ 1.2.18 はFD2枚入替 + USBデバイスで起動できます。

「FDを入れて！」のメッセージ画面

ネットワークブートの画面。

ネットワークブート画面

Memtest86+ の画面。

Memtest86+画面

■ ファイル一覧

A:.
|   appld.bat
|   autoexec.bat
|   command.com
|   config.sys
|   gpxe_all.krn
|   grub.exe
|   HOME.DAT
|   kernel.sys
|   LDFD.ZIP
|   license.txt
|   memtest
|   menu.lst
|   menu.txt
|   RDRIVE.BAT
|   ReadMe.txt
|   TDSK.EXE
|   TURBO.DAT
|   TURBODAT.exe
|   UNZIP.EXE
|   version.txt
|
+---berry90
|       default.txt
|       default2.txt
|       dynabook.txt
|       expert.txt
|       menu.txt
|       safe.txt
|       vaio.txt
|       vesa.txt
|       vesa2.txt
|
+---bgrescue
|       menu.txt
|
+---bin
|       auto_ram.bat
|       berry.bat
|       bgrescue.bat
|       copyb.bat
|       insert.bat
|       knoppix.bat
|       knoppix3.bat
|       other.bat
|       puppy.bat
|       slax.bat
|       start.bat
|       sysres.bat
|
+---driver
|       devload.com
|       himem.exe
|       keyb.exe
|       keyboard.sys
|       keybrd2.sys
|
+---freedos
|       choice.exe
|       edit.exe
|       LINLD.COM
|       xcopy.exe
|
+---get_iso
|       download.txt
|
+---grub
|       berry.conf
|       bgrescue.conf
|       insert.conf
|       insertfd.conf
|       knoppix.conf
|       knoppix3.conf
|       puppy.conf
|       slax.conf
|       sysres.conf
|
+---inse12
|       default.txt
|       expert.txt
|       failsafe.txt
|       fb1024.txt
|       fb1280.txt
|       fb800.txt
|       menu.txt
|       menu_usb.txt
|       text.txt
|       vesa.txt
|
+---knop5
|       default.txt
|       failsafe.txt
|       fb1024.txt
|       fb1280.txt
|       fb800.txt
|       menu.txt
|       test.txt
|       text.txt
|       vesa.txt
|
+---knop53
|       default.txt
|       failsafe.txt
|       fb1024.txt
|       fb1280.txt
|       fb800.txt
|       menu.txt
|       test.txt
|       text.txt
|       vesa.txt
|
+---puppy400
|       menu.txt
|
+---slax5
|       default.txt
|       menu.txt
|       safe.txt
|       vesa.txt
|       xconf.txt
|
\---sysres1
        menu.txt

■ Linuxローダ

LINLD.COMとloadlin.exeについては下記ページにて。

■ 別の Linux を起動

OS選択メニュー画面は【x】でキャンセルして、コマンドラインからother.bat を実行します。

  1. 分割FDを作成しておく
  2. 必要ならoptions.txtを作成する
  3. FDを順番に読み込ませる
  4. カーネルとinitrdを「ありがちな」名前で検索
  5. options.txtの場所を指定する
  6. 追加のパラメータがあれば入力する

オプション（パラメータ）の指定が必要な場合は、シコシコ入力するか、options.txt をFDなどに作成しておきます。

指定方法や画面など下記ページの「from 【from 【Load Ramdisk】】」の方とおんなじです。

■ 備考

LiveCDのファイルを変更している場合

サブディレクトリにまとめてるとか、マルチブートの為ディレクトリ名を変えてるとか。下記はデフォルト以外の選択対象。LINLD実行前に選択画面が表示されます。

  • KNOPPIX 5.3.1
    • knoppix3\KNOPPIX
  • SLAX 5.1.8.1-3
    • slax\livecd.sgn
    • myslax\livecd.sgn
    • slax5\livecd.sgn
  • SystemRescueCd 1.0.4
    • sysres10\sysrcd.dat
  • Berry Linux 0.90
    • berry90\BERRY
  • Puppy Linux 4.1.2.1
    • 元々サブディレクトリも検索してくれるらしい？（/puppyなんとかな名前にしとけばいいのかな？）

この場合、RAMドライブにオプションを追記した temp.txt を書き込みます。KNOPPIX5.3.1なら コピーされたオプションファイル %ramdrv%\knop53\temp.txt に knoppix_dir=knoppix3 を追記します。

■ 注意点

故障デバイスがあると...

（一概に断言はできませんが）故障あるいは不良デバイスがあるとBIOSで無効にしないと初期化中に止まってしまうことがあります。

なるべく新しいフロッピーで

古いものでは読み込みでエラーが出たり、エラー発生後にファイルが壊れたりすることも。

フロッピーを確認しませう！

いぁ、新品でもおかしい時ありますから。

Windows上では不良セクタがあっても使えてしまったりしますから、 format コマンド打つべし。

format a:

    1,457,664 バイト : 全ディスク領域
        1,024 バイト : 不良セクタ
    1,456,640 バイト : 使用可能ディスク領域

不良セクタがないか、「パオーパオーン」な雄叫び（笑）が1,2回じゃなく数十回も発生しないかとか確認しませう。

Linux LiveCD側の注意点？
「Linux起動後に」USBデバイスが認識されない

いわゆる「シェルに落ちる〜」ってやつですね。「/KNOPPIX/KNOPPIX が見つからないYO!」です。

ブートメニュー

Linux起動後の初期化中にUSBデバイスが認識されない場合は、 Linux起動直後、または「Checkin for USB...」などのメッセージが表示されている時にUSBポートを挿し直すと認識されることがあります。

USB CDだとあんまり問題ないのになぁ。（あくまでウチでは）

シャットダウン
  • SLAXでは、acpi=off を指定してるので自動で電源は切れない。「Power Down」などのメッセージで止まったら電源ボタンを押す
  • SystemRescueCdでもそうかも。
  • 他のLinuxでも acpi=off や noacpi “とか”を指定しないと起動できないことがあるかも。
USB FDドライブ

USB FDドライブでブートする際は、カーネルとinitrdロード後にUSBポートを抜いてしまった方がいいかも。デバイスの検出で時間がかかるので。

■ BG-Rescue Linux

後で使い道なんかを書く予定ですが...テキトウですが書いてみました。

USBデバイスは不要。FD +2枚のみで起動できます（vmlinuzとinitrd.imgをそれぞれFDにコピーしておく）。NTFS書き込みも可能なので、FDブート→ネットワーク（インターネットからダウンロードもおｋ）から、またはUSBデバイスからLiveCDイメージをHDにコピー→、GRUB起動ディスクなどからLiveCDをブートさせることができます。

■ 関連リンク

Linux LiveCD
FreeDOS
LINLD.COM
UNZIP.EXE

UNZIP.EXE(unz552x3.exe)

TDSK.EXE

tdsk242b

TURBODAT.exe (Finds the RAMdrive or RAMdisk created by Turbodisk v2.42)

TURBODAT.exe version 0.1

GRUB for DOS
HOME 0 | Diary 1 |
Written by yassy