'==================================================================
'デスクトップとクイック起動に、スタート画面 (Windows Key) のショートカットを作成しますYO！
'http://www10.plala.or.jp/palm84/wsh.html
'http://d.hatena.ne.jp/palm84/20121105/1352111636
'http://www10.plala.or.jp/palm84/archives/wsh/Win8_CreateSendKeys_Winkeys.vbs.txt
'https://eu7w9wsmf6a74xyjdfzl3q-on.drv.tw/archives/wsh/Win8_CreateSendKeys_Winkeys.vbs.txt
'==================================================================
'Shell オブジェクトを作成
Set objShell = WScript.CreateObject("WScript.Shell")
'FileSystemObject オブジェクトを作成
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Const ForReading = 1, ForWriting = 2, ForAppending = 8

MyKakunin

'*** 環境変数とか取得 ***
Desktop = objShell.SpecialFolders("Desktop")
QuickLaunch = objShell.ExpandEnvironmentStrings("%APPDATA%\Microsoft\Internet Explorer\Quick Launch")

'*** スタート画面 (Windows Key) ***
Title = "スタート"
strFile = QuickLaunch & "\Windows_SendKeys_WinKey.vbs"
strWorkingDirectory = ""
strIcon = "%SystemRoot%\system32\imageres.dll, 240"
If objFSO.FileExists(strFile) Then
		MySC
	Else
		Set objTxt = objFSO.OpenTextFile(strFile, ForWriting, true, -2)
		objTxt.WriteLine "Set objShell = WScript.CreateObject(""WScript.Shell"")"
		objTxt.WriteLine "objShell.SendKeys ""^{Esc}"""
		objTxt.WriteLine "Set objShell = Nothing"
		objTxt.Close
		Set objFile = objFSO.GetFile(strFile)
		objFile.Attributes = objFile.Attributes + 2
		MySC
End If

Set objTxt = Nothing
Set objShortCut = Nothing
Set objFSO = Nothing
Set objShell = Nothing

'*********************************************************
'Sub MyKakunin
'*********************************************************
Sub MyKakunin
Kakunin = MsgBox ("スタート画面 のショートカットを作りますのん？ (´･ω･`)", 65 ,"スタート画面 のショートカットを作るＹＯ！  (´･ω･`) ") 
If Kakunin = 2 Then
	WScript.Quit
End If
End Sub

'*********************************************************
'Sub MySC
'*********************************************************
Sub MySC
strShortCut = QuickLaunch & "\" & Title & ".lnk"
'*** ショートカットオブジェクトを作成 ***
Set objShortCut = objShell.CreateShortcut(strShortCut)
With objShortCut
' リンク先
	.TargetPath = strFile
' 作業フォルダ
	.WorkingDirectory = strWorkingDirectory
' 引数
	.Arguments = "" 
' コメント
	.Description = ""
' アイコン
	.IconLocation = strIcon
End With
objShortCut.Save

' ショートカットを DeskTop へコピー
objFSO.CopyFile strShortCut, DeskTop & "\"
'WScript.Echo strFileName & "にショートカットを作成しました。" 
MsgBox "デスクトップとクイック起動にショートカットを作成しました YO！"  & vbcrlf & vbcrlf & Title,64 ,"(´･ω･`) クマー！ "

End Sub