Option Explicit

Dim objFSO,objTxt,objShell,strPrograms,strWindir
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objTxt = objFSO.OpenTextFile("OperatingSystem1.txt", 8, true, -2)
Set objShell = WScript.CreateObject("WScript.Shell")
strWindir = objShell.ExpandEnvironmentStrings("%windir%")
strPrograms = objShell.ExpandEnvironmentStrings("%ProgramFiles%")


MyOperatingSystem
MyRegRead
MyFileVer
objTxt.WriteBlankLines (1)

objTxt.Close
objShell.Run "OperatingSystem1.txt"
Set objTxt = Nothing
Set objFSO = Nothing
Set objShell = Nothing

'*********************************************************
'* Sub MyOperatingSystem
'*********************************************************
Sub MyOperatingSystem
	On Error Resume Next
	Dim strComputer, objWMIService, colItems, objItem
	strComputer = "."
	Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
	Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)
	For Each objItem in colItems
    	objTxt.WriteLine objItem.OSArchitecture
    	objTxt.WriteLine objItem.Caption
    	objTxt.WriteLine "Version   : " & objItem.Version
    	objTxt.WriteLine "CSDVersion: " & objItem.CSDVersion
    	objTxt.WriteLine "WindowsDirectory: " & objItem.WindowsDirectory
    	objTxt.WriteLine "搭載物理メモリ  : " & Round(objItem.TotalVisibleMemorySize / 1024) & " MB"
    	objTxt.WriteLine "空き物理メモリ  : " & Round(objItem.FreePhysicalMemory / 1024) & " MB"
    	objTxt.WriteLine "最大仮想メモリ  : " &  Round(objItem.TotalVirtualMemorySize / 1024) & " MB"
	Next
	Set objWMIService = Nothing
End Sub

'*********************************************************
'* Sub MyRegRead -- レジストリエントリを表示
'*********************************************************
Sub MyRegRead
	Const strKey1 = "HKLM\SOFTWARE\Microsoft\Internet Explorer\Version"
	Const strKey2 = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\MinorVersion"
	objTxt.WriteLine "Internet Explorer - Version      : " & objShell.RegRead(strKey1)
	objTxt.WriteLine "Internet Explorer - MinorVersion : " & objShell.RegRead(strKey2)
End Sub

'*********************************************************
'* Sub MyFileVer -- ファイルのバージョンを表示
'*********************************************************
Sub MyFileVer
	objTxt.WriteLine "Internet Explorer - File Version : " & objFSO.GetFileVersion(strPrograms & "\Internet Explorer\iexplore.exe")
End Sub