@echo off
title %~nx0
REM ********************************************************************
REM   * 右クリック【送る】から Windows Defender でウイルススキャン
REM  http://www10.plala.or.jp/palm84/commandline.html
REM  http://www10.plala.or.jp/palm84/archives/commandline/backup/Scan_Defender_sendto.bat.txt
REM  https://eu7w9wsmf6a74xyjdfzl3q-on.drv.tw/archives/commandline/backup/Scan_Defender_sendto.bat.txt
REM ********************************************************************
if "%~1%"=="" GOTO NO_PARAM
set "Defender=%ProgramFiles%\Windows Defender\MpCmdRun.exe"
REM #####################################
REM ### 引数で指定したファイルをチェック
REM #####################################
:PARAM
if "%~1"=="" GOTO DONE
set "filename=%~1"
echo:
echo  ====================================================================
echo   * %filename% 
echo  ====================================================================
echo:
"%Defender%" -Scan -ScanType 3 -File "%filename%"
shift
GOTO PARAM
REM #####################################
REM ### NO_PARAM
REM #####################################
:NO_PARAM
echo:
echo        ==============================================================
echo                    ！引数（ファイル指定）がないですYO！
echo        ==============================================================
echo:
GOTO END
REM #####################################
REM ### DONE
REM #####################################
:DONE
echo:
echo        **************************************************************
echo        ************              Done !                  ************
echo        **************************************************************
echo:
REM #####################################
REM ### END
REM #####################################
:END
echo:
echo                     *** 何かキーを押すと閉じます *** 
echo:
pause >nul