@echo off
title %~nx0
ver | find "Version 6" >nul && set osver=vista
if "%osver%"=="vista" (
if /i not "%cd%"=="%windir%\system32" GOTO UAC
pushd %~dp0
)
REM check dd.exe
if exist dd.exe set ddexe=ok
if exist .\dd\dd.exe set ddexe=ok
if "%ddexe%"=="" GOTO NOTHING1
echo:
echo         **************************************************************
echo         *                                                            *
echo         * ===イメージファイルをAドライブのフロッピーへ書込します === *
echo         *                                                            *
echo         * ****            dd.exe が必要です                     **** *
echo         *                                                            *
echo         **************************************************************
echo:
echo                  フロッピーをAドライブにセットしてクダサイ
echo:
echo:
echo                   続行しますか？ 中断は xボタン or Ctrl-C
echo:
echo                     *** 何かキーを押すと続行します *** 
pause >nul

set path=.\dd;%path%
if not exist A: GOTO NONFD

set nakami=nasi
dir /a /b A:\ >nul 2>nul && set nakami=ari
if "%nakami%"=="nasi" GOTO ASK
cls
echo:
echo:
echo        --------------------------------------------------------------
echo        --------------------------------------------------------------
echo        フロッピーにファイルがあります。このフロッピーでほんまにおｋ？
echo        --------------------------------------------------------------
echo        --------------------------------------------------------------
echo:
set /p select=       [y,N] : 
echo:
if /i "%select%"=="y" GOTO ASK
GOTO CANCEL


:ASK
cls
echo:
echo        ==============================================================
echo:
echo            *** 書き込むイメージファイルを指定してください ***
echo:
echo                      * 中断するには qq を入れてEnter *
echo:
echo        ==============================================================
echo:
set /p filename=  ファイル : 
echo:
for /f "usebackq delims=" %%I in ('%filename%') do set filename=%%~I
if /i "%filename%"=="qq" GOTO CANCEL
if "%filename%"=="" echo                   ファイルを指定シテクダサイ!! && GOTO WAIT
for /f "delims=" %%I in ("%filename%") do set filename=%%~fI
if not exist "%filename%" echo                   %filename% がありません!! && GOTO WAIT
for %%x in ("%filename%") do set file_test=%%~ax
if "%file_test:~0,1%"=="d" echo  * %filename% はディレクトリです!! && GOTO WAIT
GOTO NAME
echo:

:WAIT
echo:
echo                     *** 何かキーを押すと続行します *** 
echo:
pause >nul
GOTO ASK

:NAME
echo:
echo   書き込むファイル名は
echo    %filename%
echo                  よろしいですか？
echo:
echo                     *** 何かキーを押すと続行します *** 
echo:
pause >nul
GOTO WRITE


:WRITE
cls
echo:
echo:
echo:
echo        --------------------------------------------------------------
echo         ..... dd コマンドでフロッピーへ書き込みしています .....
echo        --------------------------------------------------------------
echo:
echo:
dd if="%filename%" of=\\.\A:  bs=10k count=144 --progress
echo:
if not "%errorlevel%"=="0" GOTO ERROR
if "%errorlevel%"=="0" GOTO DONE


REM #####################################
REM ### NO File
REM #####################################
:NONFD
echo:
echo            !!       フロッピーがありません？              !!
GOTO END

:NOTHING1
echo:
echo        ==============================================================
echo                     dd.exe がありませんです...
echo        ==============================================================
GOTO NONFILE

:NOTHING2
echo:
echo        ==============================================================
echo                    %filename% がありませんです...
echo        ==============================================================
GOTO NONFILE

:NONFILE
echo:
echo                    ! ファイルがないので中断します...!
echo:
GOTO END

REM #####################################
REM ### ERROR
REM #####################################
:ERROR
echo:
echo                      ** !!!    エラー出ますた !    !!! **
GOTO END

:CANCEL
echo:
echo                        キャンセルしますた...
GOTO END

REM #####################################
REM ### UAC
REM #####################################
:UAC
echo:
echo:
echo:
echo        ！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！
echo:
echo                  ！「管理者として実行」してくださいマセ ！
echo:
echo        ！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！
echo:
GOTO END

REM #####################################
REM ### DONE
REM #####################################
:DONE
echo                          正常に終了しますた...
GOTO END

REM #####################################
REM ### END
REM #####################################
:END
echo:
echo                     *** 何かキーを押すと閉じます *** 
pause >nul