@echo off
title %~nx0
REM ********************************************************************
REM   * tree コマンドの出力を書き出し
REM  http://www10.plala.or.jp/palm84/commandline.html
REM  http://www10.plala.or.jp/palm84/archives/commandline/backup/Dir_tree_sendto.bat.txt
REM  https://eu7w9wsmf6a74xyjdfzl3q-on.drv.tw/archives/commandline/backup/Dir_tree_sendto.bat.txt
REM ********************************************************************
if "%~1"=="" GOTO NO_PARAM
for %%x in ("%~a1") do set check_dir=%%~x
if /i not "%check_dir:~0,1%"=="d" GOTO FILEYAN
pushd %~dp0

REM #####################################
REM ### ログのバックアップ
REM #####################################
REM set Backup=

REM #####################################
REM ### ログファイルの指定
REM #####################################
set "log=%cd%\%~n0_log1.txt"

REM ログを指定ディレクトリに作成する場合
REM set "log=%~f1\%~n0_log1.txt"

REM #####################################
REM ### 書き出し
REM #####################################
pushd %~f1
echo:
echo      ==============================================================
echo       %cd%
echo      ==============================================================
echo:
REM pause >nul

> "%log%" echo --------------------------------------------------------------
>>"%log%" echo %date% %time:~-11,5%
>>"%log%" echo ==============================================================
>>"%log%" echo %cd%
>>"%log%" echo ==============================================================
>>"%log%" tree /f /a

if defined Backup (
copy "%log%" "%Backup%\"
)
start "" "%log%" 
GOTO :EOF

REM #####################################
REM ### NO_PARAM
REM #####################################
:NO_PARAM
echo:
echo        ==============================================================
echo                    ！引数（ファイル指定）がないですYO！
echo        ==============================================================
echo:
GOTO END

REM #####################################
REM ### FILEYAN
REM #####################################
:FILEYAN
echo:
echo        ==============================================================
echo         ！ %~1 
echo:
echo         ！      ... はディレクトリちゃいます
echo        ==============================================================
echo:
GOTO END

REM #####################################
REM ### END
REM #####################################
:END
echo:
echo                     *** 何かキーを押すと閉じます *** 
pause >nul