@echo off
title %~nx0
REM ********************************************************************
REM   * アンインストールリストをチェック
REM  http://www10.plala.or.jp/palm84/archives/commandline/backup/Check_Uninstall.bat.txt
REM  https://eu7w9wsmf6a74xyjdfzl3q-on.drv.tw/archives/commandline/backup/Check_Uninstall.bat.txt
REM ********************************************************************
REM 更新	2023.06.22 ログファイル名の日付時刻を修正

REM set now=%date%_%time%
REM set now=%now:/=%
REM set now=%now: =0%
REM set now=%now:~-20,2%%now:~-17,2%%now:~-14,5%%now:~-8,2%%now:~-5,2%
set now=%date:/=%_%time: =0%
set now=%now: =%
set now=%now:.=%
set now=%now::=%
set log=%cd%\Check_UNinstall_%now%.txt

set RegKey=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall
set RegKey6432=HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall

>>"%log%" echo =========================================================
>>"%log%" echo       *** アンインストール リストのチェック ***
>>"%log%" echo           調査日時 : %date%   %time%
>>"%log%" echo =========================================================

if defined ProgramW6432 (
>>"%log%" echo           * 64 ビット版
>>"%log%" echo =========================================================
)

for /f "usebackq tokens=3,*" %%x in (`reg query %RegKey% /s ^| findstr DisplayName ^| findstr /v ParentDisplayName ^| sort`) do (
echo %%x %%y
>>"%log%" echo %%x %%y
)

if not defined ProgramW6432 GOTO SHOW_LOG

>>"%log%" echo:
>>"%log%" echo =========================================================
>>"%log%" echo           * 32 ビット版
>>"%log%" echo =========================================================
for /f "usebackq tokens=3,*" %%x in (`reg query %RegKey6432% /s ^| findstr DisplayName ^| findstr /v ParentDisplayName ^| sort`) do (
echo %%x %%y
>>"%log%" echo %%x %%y
)
GOTO SHOW_LOG

REM #####################################
REM ### SHOW_LOG
REM #####################################
:SHOW_LOG
start "" "%log%"